Ausgabe formatieren

[zahlhans]

Ich hätte nun noch eine letzte Frage:

In einer Datei habe ich Daten in folgendem Format:

Code: Alles auswählen

a#A#1
b#B#2
c#C#3
b#A#4
c#A#5
...

der Form STRING#INTEGER#INTEGER. Ich möchte diese Ergebnisse nun tabellarisch ausgeben, also

Code: Alles auswählen

               A               B                  C             ...
a             1               ...
b             4               ...
c             5               ...
...

Der zweite Wert (die Spalten) kann mit einer Schleife durchlaufen werden und die Strings (Zeilen) sind mir auch alle bekannt (müssen also nicht erst aus der Datei bestimmt werden). Geht das evtl. mit awk? Ich habe mich bisher nur grundlegend daran versucht und es nicht hinbekommen... Mein eigentliches Problem ist dabei das Befüllen einer Zeile. Mit grep kann ich die einzelnen "Zellen" schon ermitteln, aber wie bekomme ich sie hintereinander geschrieben?

[Meillo]

Code: Alles auswählen

#!/usr/bin/awk -f

BEGIN {
        FS="#"
}

{
        rows[$1] = 1
        cols[$2] = 1
        data[$1,$2] = $3 

}

END {
        for (c in cols) {
                printf("\t%s", c) 
        }  
        printf("\n")
        for (r in rows) {
                printf("%s", r) 
                for (c in cols) {
                        if (data[r,c]) {
                                printf("\t%d", data[r,c])
                        } else {
                                printf("\t-")
                        }  
                }  
                printf("\n")
        }  
}

Sollte das liefern was du willst:

Code: Alles auswählen

$ cat data.txt 
a#A#1
b#B#2
c#C#3
b#A#4
c#A#5
  
$ ./totable.awk <data.txt 
	A	B	C
a	1	-	-
b	4	2	-
c	5	-	3

[zahlhans]

Vielen Dank! Das ist noch viel besser als erhofft. Es scheint sich zu lohnen, sich einmal näher mit awk zu beschäftigen.

[Meillo]

Es scheint sich zu lohnen, sich einmal näher mit awk zu beschäftigen.

Definitiv!

[Duff]

Es scheint sich zu lohnen, sich einmal näher mit awk zu beschäftigen.

Definitiv!

Wobei dies so auch schon wieder etwas komplizierter ist.